WSH - ショートカットの作成

ショートカットを作成するには、Shellオブジェクトの「CreateShortcut」メソッドを使う。

書式

objShell.CreateShortcut( strPath )

引数

strPath ... 作成するショートカットファイル名。ファイルへのショートカットは拡張子「.lnk」、URLへのショートカットは「.url」。

戻り値

ファイルへのショートカットの場合 ... WshShortcutオブジェクト
URLへのショートカットの場合 ... WshUrlShortcutオブジェクト

ファイルへのショートカットのサンプル

'Shellオブジェクト
Set objShell = WScript.CreateObject( "WScript.Shell" )

'デスクトップのパス
strDesktop = objShell.SpecialFolders( "Desktop" )

'デスクトップにショートカット作成
Set objShortcut = objShell.CreateShortcut( strDesktop & "\メモ帳でtest.txt.lnk" )

'------------------------------
'プロパティ設定
'------------------------------

'リンク先(対象となるファイル)
objShortcut.TargetPath = "C:\WINDOWS\notepad.exe"

'コマンドライン引数
objShortcut.Arguments = "C:\test.txt"

'作業フォルダ
objShortcut.WorkingDirectory = "C:\"

'アイコン(パス+インデックス)
objShortcut.IconLocation = "C:\WINDOWS\notepad.exe,0"

'ショートカットキー( "Alt+", "Ctrl+", "Shift+" などと共に)
objShortcut.Hotkey = "Ctrl+Shift+T"

'実行時の大きさ(1:通常ウインドウ、3:最大化、7:最小化)
objShortcut.WindowStyle = 1

'コメント(ショートカットの説明)
objShortcut.Description = "メモ帳でtest.txtを開く"

'プロパティの保存
objShortcut.Save

URLへのショートカットのサンプル

'Shellオブジェクト
Set objShell = WScript.CreateObject( "WScript.Shell" )

'デスクトップのパス
strDesktop = objShell.SpecialFolders( "Desktop" )

'デスクトップにショートカット作成
Set objShortcut = objShell.CreateShortcut( strDesktop & "\MSへのリンク.url" )

'------------------------------
'プロパティ設定
'------------------------------

'リンク先(対象となるURL)
objShortcut.TargetPath = "http://www.microsoft.com"

'プロパティの保存
objShortcut.Save

外部リンク：

• CreateShortcut メソッド - msdn内